Mercurial > gnulib

view m4/check-math-lib.m4 @ 40216:02ed6264c100

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
strfmon_l: Fix -fsanitize=address finding. * lib/strfmon_l.c: Include <errno.h>, <stdbool.h>, <stdlib.h>, <string.h>. (MAX_ARGS): Renamed from MAX_ARG_WORDS. (directive_t, directives_t): New types. (fmon_parse): New function. (rpl_strfmon_l): Don't call va_arg more often than needed for the format string. Consume 'long double' arguments in places where the format string indicates so. * modules/strfmon_l (Depends-on): Add 'stdbool'.
author Bruno Haible <bruno@clisp.org>
date Sat, 09 Mar 2019 23:30:40 +0100
parents b06060465f09
children
line wrap: on
line source

# check-math-lib.m4 serial 4
dnl Copyright (C) 2007, 2009-2019 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
dnl
dnl gl_CHECK_MATH_LIB (VARIABLE, EXPRESSION [, EXTRA-CODE])
dnl
dnl Sets the shell VARIABLE according to the libraries needed by EXPRESSION
dnl to compile and link: to the empty string if no extra libraries are needed,
dnl to "-lm" if -lm is needed, or to "missing" if it does not compile and
dnl link either way.
dnl
dnl Example: gl_CHECK_MATH_LIB([ROUNDF_LIBM], [x = roundf (x);])
AC_DEFUN([gl_CHECK_MATH_LIB], [
  save_LIBS=$LIBS
  $1=missing
  for libm in "" "-lm"; do
    LIBS="$save_LIBS $libm"
    AC_LINK_IFELSE([AC_LANG_PROGRAM([[
         #ifndef __NO_MATH_INLINES
         # define __NO_MATH_INLINES 1 /* for glibc */
         #endif
         #include <math.h>
         $3
         double x;]],
      [$2])],
      [$1=$libm
break])
  done
  LIBS=$save_LIBS
])