Mercurial > gnulib

view m4/sinf.m4 @ 40216:02ed6264c100

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
strfmon_l: Fix -fsanitize=address finding. * lib/strfmon_l.c: Include <errno.h>, <stdbool.h>, <stdlib.h>, <string.h>. (MAX_ARGS): Renamed from MAX_ARG_WORDS. (directive_t, directives_t): New types. (fmon_parse): New function. (rpl_strfmon_l): Don't call va_arg more often than needed for the format string. Consume 'long double' arguments in places where the format string indicates so. * modules/strfmon_l (Depends-on): Add 'stdbool'.
author Bruno Haible <bruno@clisp.org>
date Sat, 09 Mar 2019 23:30:40 +0100
parents b06060465f09
children
line wrap: on
line source

# sinf.m4 serial 3
dnl Copyright (C) 2011-2019 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_FUNC_SINF],
[
  AC_REQUIRE([gl_MATH_H_DEFAULTS])
  AC_REQUIRE([gl_FUNC_SIN])

  dnl Persuade glibc <math.h> to declare sinf().
  AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])

  dnl Test whether sinf() exists. Assume that sinf(), if it exists, is
  dnl defined in the same library as sin().
  save_LIBS="$LIBS"
  LIBS="$LIBS $SIN_LIBM"
  AC_CHECK_FUNCS([sinf])
  LIBS="$save_LIBS"
  if test $ac_cv_func_sinf = yes; then
    SINF_LIBM="$SIN_LIBM"
  else
    HAVE_SINF=0
    dnl If the function is declared but does not appear to exist, it may be
    dnl defined as an inline function. In order to avoid a conflict, we have
    dnl to define rpl_sinf, not sinf.
    AC_CHECK_DECLS([sinf], [REPLACE_SINF=1], , [[#include <math.h>]])
    SINF_LIBM="$SIN_LIBM"
  fi
  AC_SUBST([SINF_LIBM])
])