Mercurial > gnulib

view m4/net_if_h.m4 @ 40214:452ab00796c7

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Fix undefined behaviour. * lib/bitrotate.h (rotl16, rotr16, rotl8, rotr8): Case x to 'unsigned int', to avoid shift operations on 'int'. * lib/xmemdup0.c (xmemdup0): Don't invoke memcpy with a zero size. * tests/test-count-leading-zeros.c (main): Use a random number that has as many bits as TYPE, not only 2*15 or 2*31 bits. * tests/test-count-trailing-zeros.c (main): Likewise. * tests/test-count-one-bits.c (main): Likewise. * tests/test-memmem.c: Don't include "null-ptr.h". (main): Use zerosize_ptr() instead of null_ptr(). * modules/memmem-tests (Files): Remove tests/null-ptr.h.
author Bruno Haible <bruno@clisp.org>
date Sat, 09 Mar 2019 20:32:25 +0100
parents b06060465f09
children
line wrap: on
line source

# net_if_h.m4 serial 1
dnl Copyright (C) 2006-2019 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_HEADER_NET_IF],
[
  AC_CACHE_CHECK([whether <net/if.h> is self-contained],
    [gl_cv_header_net_if_h_selfcontained],
    [
      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <net/if.h>]],
                                         [[struct if_nameindex ni;]])],
        [gl_cv_header_net_if_h_selfcontained=yes],
        [gl_cv_header_net_if_h_selfcontained=no])
    ])
  if test $gl_cv_header_net_if_h_selfcontained = yes; then
    NET_IF_H=''
  else
    NET_IF_H='net/if.h'
    AC_CHECK_HEADERS([net/if.h], [], [], [[#include <sys/socket.h>]])
    gl_NEXT_HEADERS([net/if.h])
    if test $ac_cv_header_net_if_h = yes; then
      HAVE_NET_IF_H=1
    else
      HAVE_NET_IF_H=0
    fi
    AC_SUBST([HAVE_NET_IF_H])
  fi
  AC_SUBST([NET_IF_H])
  AM_CONDITIONAL([GL_GENERATE_NET_IF_H], [test -n "$NET_IF_H"])
])