Mercurial > gnulib

view m4/sched_h.m4 @ 40214:452ab00796c7

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Fix undefined behaviour. * lib/bitrotate.h (rotl16, rotr16, rotl8, rotr8): Case x to 'unsigned int', to avoid shift operations on 'int'. * lib/xmemdup0.c (xmemdup0): Don't invoke memcpy with a zero size. * tests/test-count-leading-zeros.c (main): Use a random number that has as many bits as TYPE, not only 2*15 or 2*31 bits. * tests/test-count-trailing-zeros.c (main): Likewise. * tests/test-count-one-bits.c (main): Likewise. * tests/test-memmem.c: Don't include "null-ptr.h". (main): Use zerosize_ptr() instead of null_ptr(). * modules/memmem-tests (Files): Remove tests/null-ptr.h.
author Bruno Haible <bruno@clisp.org>
date Sat, 09 Mar 2019 20:32:25 +0100
parents b06060465f09
children
line wrap: on
line source

# sched_h.m4 serial 11
dnl Copyright (C) 2008-2019 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl Written by Bruno Haible.

AC_DEFUN([gl_SCHED_H],
[
  AC_REQUIRE([AC_CANONICAL_HOST])
  AC_CHECK_HEADERS_ONCE([sys/cdefs.h])
  AC_COMPILE_IFELSE(
    [AC_LANG_PROGRAM([[
       #include <sched.h>
       struct sched_param a;
       int b[] = { SCHED_FIFO, SCHED_RR, SCHED_OTHER };
       pid_t t1;
     ]])],
    [SCHED_H=''],
    [SCHED_H='sched.h'
     AC_CHECK_HEADERS([sched.h], [], [],
       [[#if HAVE_SYS_CDEFS_H
          #include <sys/cdefs.h>
         #endif
       ]])
     gl_NEXT_HEADERS([sched.h])

     if test "$ac_cv_header_sched_h" = yes; then
       HAVE_SCHED_H=1
     else
       HAVE_SCHED_H=0
     fi
     AC_SUBST([HAVE_SCHED_H])

     if test "$HAVE_SCHED_H" = 1; then
       AC_CHECK_TYPE([struct sched_param],
         [HAVE_STRUCT_SCHED_PARAM=1], [HAVE_STRUCT_SCHED_PARAM=0],
         [[#if HAVE_SYS_CDEFS_H
            #include <sys/cdefs.h>
           #endif
           #include <sched.h>
         ]])
     else
       HAVE_STRUCT_SCHED_PARAM=0
       case "$host_os" in
         os2*)
           dnl On OS/2 kLIBC, struct sched_param is in spawn.h.
           AC_CHECK_TYPE([struct sched_param],
             [HAVE_STRUCT_SCHED_PARAM=1], [],
             [#include <spawn.h>])
           ;;
         vms)
           dnl On OpenVMS 7.2 or newer, struct sched_param is in pthread.h.
           AC_CHECK_TYPE([struct sched_param],
             [HAVE_STRUCT_SCHED_PARAM=1], [],
             [#include <pthread.h>])
           ;;
       esac
     fi
     AC_SUBST([HAVE_STRUCT_SCHED_PARAM])

     if test "$ac_cv_header_sys_cdefs_h" = yes; then
       HAVE_SYS_CDEFS_H=1
     else
       HAVE_SYS_CDEFS_H=0
     fi
     AC_SUBST([HAVE_SYS_CDEFS_H])

     dnl Ensure the type pid_t gets defined.
     AC_REQUIRE([AC_TYPE_PID_T])
    ])
  AC_SUBST([SCHED_H])
  AM_CONDITIONAL([GL_GENERATE_SCHED_H], [test -n "$SCHED_H"])
])