Mercurial > gnulib

view m4/sys_select_h.m4 @ 30232:93e5702f1344

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
strengthen self-containedness check for sys/select.h 2008-09-29 Paolo Bonzini <bonzini@gnu.org> Bruno Haible <bruno@clisp.org> * lib/sys_select.in.h: Include sys/time.h. * m4/sys_select.h.m4: Test that struct timeval is fully defined. * modules/sys_select: Depend on sys_time. * tests/test-sys_select.c: Test that sys/select.h defines struct timeval fully.
author Paolo Bonzini <bonzini@gnu.org>
date Mon, 29 Sep 2008 12:02:35 +0200
parents 051ed487f38b
children ca7f9b88efc1
line wrap: on
line source

# sys_select_h.m4 serial 5
dnl Copyright (C) 2006-2008 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_HEADER_SYS_SELECT],
[
  AC_REQUIRE([gl_HEADER_SYS_SOCKET])
  AC_CACHE_CHECK([whether <sys/select.h> is self-contained],
    [gl_cv_header_sys_select_h_selfcontained],
    [
      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/select.h>]],
					 [[struct timeval b;]])],
        [gl_cv_header_sys_select_h_selfcontained=yes],
        [gl_cv_header_sys_select_h_selfcontained=no])
    ])
  if test $gl_cv_header_sys_select_h_selfcontained = yes; then
    SYS_SELECT_H=''
  else
    SYS_SELECT_H='sys/select.h'
    gl_CHECK_NEXT_HEADERS([sys/select.h])
    if test $ac_cv_header_sys_select_h = yes; then
      HAVE_SYS_SELECT_H=1
    else
      HAVE_SYS_SELECT_H=0
    fi
    AC_SUBST([HAVE_SYS_SELECT_H])
    gl_PREREQ_SYS_H_WINSOCK2
  fi
  AC_SUBST([SYS_SELECT_H])
  if test x$ac_cv_header_winsock2_h = xyes; then
    AC_LIBOBJ(winsock-select)
  fi
])