# HG changeset patch
# User Paolo Bonzini <bonzini@gnu.org>
# Date 1226401294 -3600
# Node ID f532d334e68edc17bc3e302c035e155b5283eecf
# Parent  10738faa679c182b1030e6bc3c745e4fb28cea80
warnings: Support non-literal arguments, and let the user choose the variable

2008-11-11  Paolo Bonzini  <bonzini@gnu.org>

	* m4/warnings.m4: Almost complete rewrite. :-)

diff -r 10738faa679c -r f532d334e68e ChangeLog
--- a/ChangeLog	Tue Nov 11 10:29:18 2008 +0100
+++ b/ChangeLog	Tue Nov 11 12:01:34 2008 +0100
@@ -1,3 +1,7 @@
+2008-11-11  Paolo Bonzini  <bonzini@gnu.org>
+
+	* m4/warnings.m4: Almost complete rewrite. :-)
+
 2008-11-10  Simon Josefsson  <simon@josefsson.org>
 
 	* modules/warnings: New module.
diff -r 10738faa679c -r f532d334e68e m4/warnings.m4
--- a/m4/warnings.m4	Tue Nov 11 10:29:18 2008 +0100
+++ b/m4/warnings.m4	Tue Nov 11 12:01:34 2008 +0100
@@ -13,22 +13,38 @@
   AC_ARG_VAR(WARN_CFLAGS, [C compiler warning flags])
 ])
 
-# gl_WARN_ADD([parameter]) adds parameter to WARN_CFLAGS if compiler
-# supports it.  For example, use gl_WARN_ADD([-Werror]).
-AC_DEFUN([gl_WARN_ADD],
-[
-  pushdef([param],[translit([$1],[ABCDEFGHIJKLMNOPQRSTUVWXYZ./-],
-                                 [abcdefghijklmnopqrstuvwxyz___])])
+# gl_AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
+# ----------------------------------------------------
+# Provide the functionality of AS_VAR_IF if Autoconf does not have it.
+m4_ifdef([AS_VAR_IF],
+[m4_copy([AS_VAR_IF], [gl_AS_VAR_IF])],
+[m4_define([gl_AS_VAR_IF],
+[AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
+
+# gl_AS_VAR_APPEND(VAR, VALUE)
+# ----------------------------
+# Provide the functionality of AS_VAR_APPEND if Autoconf does not have it.
+m4_ifdef([AS_VAR_APPEND],
+[m4_copy([AS_VAR_APPEND], [gl_AS_VAR_APPEND])],
+[m4_define([gl_AS_VAR_APPEND],
+[AS_VAR_SET([$1], [AS_VAR_GET([$1])$2])])])
 
-  AC_CACHE_CHECK([whether compiler handles $1], [gl_cv_warn[]param[]], [
-    save_CFLAGS="$CFLAGS"
-    CFLAGS="${CFLAGS} $1"
-    AC_PREPROC_IFELSE([AC_LANG_PROGRAM([])],
-                       gl_cv_warn[]param=yes, gl_cv_warn[]param=no)
-    CFLAGS="$save_CFLAGS"
-  ])
-
-  if test $gl_cv_warn[]param = "yes"; then
-    WARN_CFLAGS="$WARN_CFLAGS $1"
-  fi
+# gl_WARN_ADD(PARAMETER, [VARIABLE = WARN_CFLAGS])
+# ------------------------------------------------
+# Adds parameter to WARN_CFLAGS if the compiler supports it.  For example,
+# gl_WARN_ADD([-Wparentheses]).
+AC_DEFUN([gl_WARN_ADD],
+[AS_VAR_PUSHDEF([gl_Warn], [gl_cv_warn_$1])dnl
+AC_CACHE_CHECK([whether compiler handles $1], [gl_Warn], [
+  save_CFLAGS="$CFLAGS"
+  CFLAGS="${CFLAGS} $1"
+  AC_PREPROC_IFELSE([AC_LANG_PROGRAM([])],
+                    [AS_VAR_SET([gl_Warn], [yes])],
+		    [AS_VAR_SET([gl_Warn], [no])])
+  CFLAGS="$save_CFLAGS"
 ])
+AS_VAR_PUSHDEF([gl_Flags], m4_if([$2], [], [[WARN_CFLAGS]], [[$2]]))dnl
+gl_AS_VAR_IF([gl_Warn], [yes], [gl_AS_VAR_APPEND([gl_Flags], [" $1"])])
+AS_VAR_POPDEF([gl_Flags])dnl
+AS_VAR_POPDEF([gl_Warn])dnl
+])