Mercurial > octave-nkf

comparison m4/acx_lapack.m4 @ 9645:4531741e5236

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
configure tweaks
author John W. Eaton <jwe@octave.org>
date Tue, 15 Sep 2009 13:48:39 -0400
parents acx_lapack.m4@fd13f9f7dbac
children
comparison
equal deleted inserted replaced
9644:080e11f1b0c1 9645:4531741e5236
1 # ===========================================================================
2 # http://autoconf-archive.cryp.to/acx_lapack.html
3 # ===========================================================================
4 #
5 # SYNOPSIS
6 #
7 # ACX_LAPACK([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
8 #
9 # DESCRIPTION
10 #
11 # This macro looks for a library that implements the LAPACK linear-algebra
12 # interface (see http://www.netlib.org/lapack/). On success, it sets the
13 # LAPACK_LIBS output variable to hold the requisite library linkages.
14 #
15 # To link with LAPACK, you should link with:
16 #
17 # $LAPACK_LIBS $BLAS_LIBS $LIBS $FLIBS
18 #
19 # in that order. BLAS_LIBS is the output variable of the ACX_BLAS macro,
20 # called automatically. FLIBS is the output variable of the
21 # AC_F77_LIBRARY_LDFLAGS macro (called if necessary by ACX_BLAS), and is
22 # sometimes necessary in order to link with F77 libraries. Users will also
23 # need to use AC_F77_DUMMY_MAIN (see the autoconf manual), for the same
24 # reason.
25 #
26 # The user may also use --with-lapack=<lib> in order to use some specific
27 # LAPACK library <lib>. In order to link successfully, however, be aware
28 # that you will probably need to use the same Fortran compiler (which can
29 # be set via the F77 env. var.) as was used to compile the LAPACK and BLAS
30 # libraries.
31 #
32 # ACTION-IF-FOUND is a list of shell commands to run if a LAPACK library
33 # is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
34 # is not found. If ACTION-IF-FOUND is not specified, the default action
35 # will define HAVE_LAPACK.
36 #
37 # LAST MODIFICATION
38 #
39 # 2008-06-29
40 #
41 # COPYLEFT
42 #
43 # Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
44 #
45 # This program is free software: you can redistribute it and/or modify it
46 # under the terms of the GNU General Public License as published by the
47 # Free Software Foundation, either version 3 of the License, or (at your
48 # option) any later version.
49 #
50 # This program is distributed in the hope that it will be useful, but
51 # WITHOUT ANY WARRANTY; without even the implied warranty of
52 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
53 # Public License for more details.
54 #
55 # You should have received a copy of the GNU General Public License along
56 # with this program. If not, see <http://www.gnu.org/licenses/>.
57 #
58 # As a special exception, the respective Autoconf Macro's copyright owner
59 # gives unlimited permission to copy, distribute and modify the configure
60 # scripts that are the output of Autoconf when processing the Macro. You
61 # need not follow the terms of the GNU General Public License when using
62 # or distributing such scripts, even though portions of the text of the
63 # Macro appear in them. The GNU General Public License (GPL) does govern
64 # all other use of the material that constitutes the Autoconf Macro.
65 #
66 # This special exception to the GPL applies to versions of the Autoconf
67 # Macro released by the Autoconf Macro Archive. When you make and
68 # distribute a modified version of the Autoconf Macro, you may extend this
69 # special exception to the GPL to apply to your modified version as well.
70
71 AC_DEFUN([ACX_LAPACK], [
72 AC_REQUIRE([ACX_BLAS])
73 acx_lapack_ok=no
74
75 AC_ARG_WITH(lapack,
76 [AC_HELP_STRING([--with-lapack=<lib>], [use LAPACK library <lib>])])
77 case $with_lapack in
78 yes | "") ;;
79 no) acx_lapack_ok=disable ;;
80 -* | */* | *.a | *.so | *.so.* | *.o) LAPACK_LIBS="$with_lapack" ;;
81 *) LAPACK_LIBS="-l$with_lapack" ;;
82 esac
83
84 # Get fortran linker name of LAPACK function to check for.
85 AC_F77_FUNC(cheev)
86
87 # We cannot use LAPACK if BLAS is not found
88 if test "x$acx_blas_ok" != xyes; then
89 acx_lapack_ok=noblas
90 LAPACK_LIBS=""
91 fi
92
93 # First, check LAPACK_LIBS environment variable
94 if test "x$LAPACK_LIBS" != x; then
95 save_LIBS="$LIBS"; LIBS="$LAPACK_LIBS $BLAS_LIBS $LIBS $FLIBS"
96 AC_MSG_CHECKING([for $cheev in $LAPACK_LIBS])
97 AC_TRY_LINK_FUNC($cheev, [acx_lapack_ok=yes], [LAPACK_LIBS=""])
98 AC_MSG_RESULT($acx_lapack_ok)
99 LIBS="$save_LIBS"
100 if test $acx_lapack_ok = no; then
101 LAPACK_LIBS=""
102 fi
103 fi
104
105 # LAPACK linked to by default? (is sometimes included in BLAS lib)
106 if test $acx_lapack_ok = no; then
107 save_LIBS="$LIBS"; LIBS="$LIBS $BLAS_LIBS $FLIBS"
108 AC_CHECK_FUNC($cheev, [acx_lapack_ok=yes])
109 LIBS="$save_LIBS"
110 fi
111
112 # Generic LAPACK library?
113 for lapack in lapack lapack_rs6k; do
114 if test $acx_lapack_ok = no; then
115 save_LIBS="$LIBS"; LIBS="$BLAS_LIBS $LIBS"
116 AC_CHECK_LIB($lapack, $cheev,
117 [acx_lapack_ok=yes; LAPACK_LIBS="-l$lapack"], [], [$FLIBS])
118 LIBS="$save_LIBS"
119 fi
120 done
121
122 AC_SUBST(LAPACK_LIBS)
123
124 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
125 if test x"$acx_lapack_ok" = xyes; then
126 ifelse([$1],,AC_DEFINE(HAVE_LAPACK,1,[Define if you have LAPACK library.]),[$1])
127 :
128 else
129 acx_lapack_ok=no
130 $2
131 fi
132 ])dnl ACX_LAPACK