Mercurial > gnulib

view m4/cbrt.m4 @ 17363:5a51fb7777a9

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
sys_select, sys_time: port 2013-01-30 Solaris 2.6 fix to Cygwin Problem reported by Marco Atzeri in <http://lists.gnu.org/archive/html/bug-gnulib/2013-03/msg00000.html>. * lib/sys_select.in.h [HAVE_SYS_SELECT_H && _CYGWIN_SYS_TIME_H]: Simply delegate to the system <sys/select.h> in this case too. Also, pay attention to _GL_SYS_SELECT_H_REDIRECT_FROM_SYS_TIME_H only if OSF/1, since otherwise Cygwin breaks, and it doesn't seem to be needed on Solaris either. * lib/sys_time.in.h [_CYGWIN_SYS_TIME_H]: Simply delgate to the system <sys/time.h> in this case.
author Paul Eggert <eggert@cs.ucla.edu>
date Tue, 19 Mar 2013 09:08:47 -0700
parents e542fd46ad6f
children 344018b6e5d7
line wrap: on
line source

# cbrt.m4 serial 2
dnl Copyright (C) 2012-2013 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_FUNC_CBRT],
[
  AC_REQUIRE([gl_MATH_H_DEFAULTS])

  dnl Persuade glibc <math.h> to declare cbrt().
  AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])

  dnl Determine CBRT_LIBM.
  gl_COMMON_DOUBLE_MATHFUNC([cbrt])

  dnl Test whether cbrt() exists.
  save_LIBS="$LIBS"
  LIBS="$LIBS $CBRT_LIBM"
  AC_CHECK_FUNCS([cbrt])
  LIBS="$save_LIBS"
  if test $ac_cv_func_cbrt = no; then
    HAVE_CBRT=0
    dnl Find libraries needed to link lib/cbrt.c.
    AC_REQUIRE([gl_FUNC_FABS])
    AC_REQUIRE([gl_FUNC_FREXP])
    AC_REQUIRE([gl_FUNC_LDEXP])
    CBRT_LIBM=
    dnl Append $FABS_LIBM to CBRT_LIBM, avoiding gratuitous duplicates.
    case " $CBRT_LIBM " in
      *" $FABS_LIBM "*) ;;
      *) CBRT_LIBM="$CBRT_LIBM $FABS_LIBM" ;;
    esac
    dnl Append $FREXP_LIBM to CBRT_LIBM, avoiding gratuitous duplicates.
    case " $CBRT_LIBM " in
      *" $FREXP_LIBM "*) ;;
      *) CBRT_LIBM="$CBRT_LIBM $FREXP_LIBM" ;;
    esac
    dnl Append $LDEXP_LIBM to CBRT_LIBM, avoiding gratuitous duplicates.
    case " $CBRT_LIBM " in
      *" $LDEXP_LIBM "*) ;;
      *) CBRT_LIBM="$CBRT_LIBM $LDEXP_LIBM" ;;
    esac
  fi
])