Mercurial > gnulib

changeset 30171:eeaa0c743274

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
New module 'sigpipe'.
author Bruno Haible <bruno@clisp.org>
date Fri, 26 Sep 2008 13:23:08 +0200
parents abd61bf1a0be
children b76e9423366a
files ChangeLog m4/sigpipe.m4 modules/sigpipe
diffstat 3 files changed, 71 insertions(+), 0 deletions(-) [+]
line wrap: on
line diff
--- a/ChangeLog	Thu Sep 25 20:33:12 2008 +0200
+++ b/ChangeLog	Fri Sep 26 13:23:08 2008 +0200
@@ -1,3 +1,8 @@
+2008-09-26  Bruno Haible  <bruno@clisp.org>
+
+	* modules/sigpipe: New file.
+	* m4/sigpipe.m4: New file.
+
 2008-09-25  Derek Price  <derek@ximbiot.com>
             Bruno Haible  <bruno@clisp.org>
 
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/m4/sigpipe.m4	Fri Sep 26 13:23:08 2008 +0200
@@ -0,0 +1,29 @@
+# sigpipe.m4 serial 1
+dnl Copyright (C) 2008 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl Tests whether SIGPIPE is provided by <signal.h>.
+dnl Sets gl_cv_header_signal_h_SIGPIPE.
+AC_DEFUN([gl_SIGNAL_SIGPIPE],
+[
+  dnl Use AC_REQUIRE here, so that the default behavior below is expanded
+  dnl once only, before all statements that occur in other macros.
+  AC_REQUIRE([gl_SIGNAL_SIGPIPE_BODY])
+])
+
+AC_DEFUN([gl_SIGNAL_SIGPIPE_BODY],
+[
+  AC_REQUIRE([AC_PROG_CC])
+  AC_CACHE_CHECK([for SIGPIPE], gl_cv_header_signal_h_SIGPIPE, [
+    AC_EGREP_CPP(booboo,[
+#include <signal.h>
+#if !defined SIGPIPE
+booboo
+#endif
+      ],
+      [gl_cv_header_signal_h_SIGPIPE=no],
+      [gl_cv_header_signal_h_SIGPIPE=yes])
+  ])
+])
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/modules/sigpipe	Fri Sep 26 13:23:08 2008 +0200
@@ -0,0 +1,37 @@
+Description:
+Emulation of POSIX compatible SIGPIPE behaviour.
+
+Files:
+m4/sigpipe.m4
+
+Depends-on:
+signal
+sigprocmask
+stdio
+unistd
+
+configure.ac:
+gl_SIGNAL_SIGPIPE
+dnl Define the C macro GNULIB_SIGPIPE to 1.
+gl_MODULE_INDICATOR([sigpipe])
+dnl Define the substituted variable GNULIB_SIGNAL_H_SIGPIPE to 1.
+AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
+GNULIB_SIGNAL_H_SIGPIPE=1
+dnl Define the substituted variable GNULIB_STDIO_H_SIGPIPE to 1.
+AC_REQUIRE([gl_STDIO_H_DEFAULTS])
+GNULIB_STDIO_H_SIGPIPE=1
+dnl Define the substituted variable GNULIB_UNISTD_H_SIGPIPE to 1.
+AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
+GNULIB_UNISTD_H_SIGPIPE=1
+
+Makefile.am:
+
+Include:
+<signal.h>
+
+License:
+LGPL
+
+Maintainer:
+Bruno Haible
+